#!/bin/csh -f
#
#	$Id: ncargf77.csh,v 1.12 1993/04/19 20:24:55 haley Exp $
#
set XLIBPATH = ""
set system   = "Sun4"
set fortran  = "f77"
set libdir   = `ncargpath lib`
set ro       = "$libdir/ncarg/robj"
set loadopts = "-cg89 -O"
set libextra = ""

if (! -d "$libdir") then
  echo "Library directory <$libdir> does not exist."
  exit 1
endif

#
# Set up special cases
#
if ("$system" == "Sun3") then
  set loadopts = "-fswitch"
else if ("$system" == "Sun4Solaris") then
  set libextra = "/usr/ucblib/libucb.a"
endif    

set newargv = "$fortran $loadopts"

set ctrans_libs = ""
set stub_file   = ""

#
# set up default libraries
#
if ("$system" == "Ardent" || "$system" == "AIX370") then
  set libncarg  =  "$ro/libncarbd.o $libdir/libncarg.a"
else
  set libncarg  =  "-lncarg"
endif
set libgks     = "-lncarg_gks"
set liblocal   = "-lncarg_loc"
set libncarg_c = "-lncarg_c"

set libmath  = "-lm"
set libX11     = "$XLIBPATH -lX11"

set smooth = "$ro/libdashsmth.o"
set quick  = "$ro/libdashline.o $ro/libconrcqck.o $ro/libconraq.o"
set super  = "$ro/libdashsupr.o $ro/libconrcspr.o $ro/libconras.o"

set libs

foreach arg ($argv)

  switch ($arg)

     case "-static":
	echo "Using static libraries"
	set libncarg="-Bstatic -lncarg -Bdynamic"
	breaksw

     case "-xgks":
	echo "Using XGKS"
	set libs="$libs -leasy_ncar"
#	set libgks="-lfxgks -lxgks -lX11 -lm"
	set libgks="-lxgks -lucb -lX11 -lm"
	breaksw

     case "-xgks_uw":
	echo "Using XGKS"
	set libs="$libs -leasy_ncar"
	set libgks="-Bstatic -lfxgks_uw -lxgks_uw -Bdynamic -lX11 -lm"
	breaksw

    case "-sungks":
        echo "Using Sun GKS"
        set libgks="-lgks77 -lgks -lsuntool -lsunwindow -lpixrect -lm"
        breaksw

    case "-smooth":
        echo "Smooth f77 of NCAR Graphics"
        set libs = "$libs $smooth"
        breaksw

    case "-super":
        echo "Super f77 of NCAR Graphics"
        set libs = "$libs $super"
        breaksw

    case "-quick":
        echo "Quick f77 of NCAR Graphics"
        set libs = "$libs $quick"
        breaksw

    case "-agupwrtx":
        echo "Autograph with PWRITX"
        set libs = "$libs $ro/libagupwrtx.o"
        breaksw

    case "-conransmooth":
        echo "Smooth Conran"
        set libs = "$libs $smooth"
        breaksw

    case "-conranquick":
        echo "Quick Conran"
        set libs = "$libs $ro/libconraq.o"
        breaksw

    case "-conransuper":
        echo "Super Conran"
        set libs = "$libs $ro/libconras.o $ro/libdashsupr.o"
        breaksw

    case "-conrecsmooth":
        echo "Smooth Conrec"
        set libs = "$libs $ro/libdashsmth.o"
        breaksw

    case "-conrecquick":
        echo "Quick Conrec"
        set libs = "$libs $ro/libconrcqck.o"
        breaksw

    case "-conrecsuper":
        echo "Super Conrec"
        set libs = "$libs $ro/libconrcspr.o $ro/libdashsupr.o"
        breaksw

    case "-dashsmooth":
        echo "Smooth Dash"
        set libs = "$libs $ro/libdashsmth.o"
        breaksw

    case "-dashquick":
    case "-dashline":
        echo "Quick Dash"
        set libs = "$libs $ro/libdashline.o"
        breaksw

    case "-dashsuper":
        echo "Super Dash"
        set libs = "$libs $ro/libdashsupr.o"
        breaksw

    case "-dashchar":
        echo "Normal Dash"
        breaksw

    case "-ictrans"
        echo "Output to ictrans"
        set ctrans_libs = `ctlib`
        set libX11   = ""
        set libmath  = ""
        set stub_file = $ro/ggkwdr_stub.o
        if ("$system" == "Sun4") then
            set libextra = "-L/usr/lang/SC1.0.1/ansi_lib -lansi"
        endif
        breaksw

    case "-noX11"
        set stub_file = $ro/ggkwdr_stub.o
        set libX11 = ""
        breaksw

    case "-*":
        set newargv = "$newargv $arg"
        breaksw

    default:
        set newargv = "$newargv $arg"
        breaksw

  endsw
end

set newargv = "$newargv $stub_file $ctrans_libs $libs $libncarg $libgks $libncarg_c $liblocal $libX11 $libmath $libextra"

echo $newargv
eval $newargv