divert(-1)
# @(#)Copyright (c), 1987, 1993 StatSci, Inc.  All rights reserved.
define(`OPTARG',`ifelse($1,,NOARG,$1)')
define(`ENCODE',`{ ENClst($*) }')
define(`ENClst',`ifelse($1,,,
`ifelse(substr($1,0,1),",`call encs00($1,eval(len($1)-2),FALSE)',`_$1')
ENClst(shift($*))')')
define(`_I',`call enci00($1,OPTARG($2))')
define(`_O',`call enco00($1,OPTARG($2))')
define(`_L',`call encl00($1,OPTARG($2))')
define(`_C',`call encs00($1,ifelse($2,,islenz($1),$2),FALSE)')
define(`_CPOS',`call encs01($1,$2,ifelse($3,,islenz($1)-$2,$3),FALSE)')
define(`_Q',`call encs00($1,ifelse($2,,islenz($1)+2,$2),TRUE)')
define(`_QPOS',`call encs01($1,$2,ifelse($3,,islenz($1)-$2,$3),TRUE)')
define(`_S',`call encc00($1,OPTARG($2),OPTARG($3),OPTARG($4))')
define(`_ST',`call encs00("`$*'",len(`$*'),FALSE)')
define(`_R',`call encr00($1,OPTARG($2),OPTARG($3),OPTARG($4))')
define(`_F',`call encf00($1,OPTARG($2),OPTARG($3))')
define(`_E',`_R($*)')
define(`_SP',`BUFPOS=BUFPOS+ifelse($1,,1,$1)')
define(`_V',`call encv00($1,$2,OPTARG($3),OPTARG($4),OPTARG($5))')
define(`_TM',`BUFPOS=1+$1*((BUFPOS+$1-2)/$1)')# tab to mltple of width
define(`_T',`BUFPOS=max0(BUFPOS,$1)')
define(`_COMMA',`call encs00(",    ",ifelse($1,,1,$1),FALSE)')
define(`_L_PAREN',`call encs00("()",1,FALSE)')
define(`_R_PAREN',`call encs00("substr((),1,1)",1,FALSE)')
undefine(`QUOTE')
define(`_QUOTE',`call encs00(CHARMAKE(34),1,FALSE)')
define(`_TABCHAR',`call encs00(TAB,1,FALSE)')
define(`_SHARP',`call encs00("#",1,.false.)')
define(`_NASYMB',`call encs00("NA_",2,FALSE)')	# final _ prevents interpretation as NA macro
define(`PRINT',`{ifelse($1,,,`ENCODE($*)')
call prtfil(STDOUT)}')
define(`FPRINT',`{ifelse($2,,,`ENCODE(shift($*))')
call prtfil($1)}')
define(`EPRINT',`{ifelse($1,,,`ENCODE($*)')
call prtfil(ERRORFC)}')
define(`ABORT',`ifelse($1,,call zzabt,
	`{EPRINT($*);call zzabt}')')
define(`CLEAR',`{ BUFPOS=0; ifelse(CHAR_VAR,yes,`BUFFER=" "',`call cfill(" ",BUFFER,BUFLEN)') }')
define(`BUFFER',encbf0)define(`BUFPOS',iqqbfl)define(`BUFLEN',256)
define(`SKIP',`{FOR(iqqtmp=0, iqqtmp<ifelse($2,,1,$2), iqqtmp=iqqtmp+1)
	call prtfil(ifelse($1,,STDOUT,$1))
}')
define(`E_FORMAT',1)
define(`F_FORMAT',-1)
divert(0)common/encbfc/encbf0
common/encbfl/iqqbfl,iqqfil
CHARACTER(encbf0,BUFLEN); integer iqqbfl,iqqfil
SCCS_ID(99980,`@(#)'print.m 3.9 last edit 2/20/93 StatSci. From BASEFILE)
