define(`xSTREAMx',divnum)
divert(-1)

# @(#)Copyright (c), 1987, 1993 StatSci, Inc.  All rights reserved.
# @(#)sccs.m 3.2 last edit 2/23/93 StatSci

define(SQUOTEIT,`''$1`'')

define(`SCCS_ID',`ifdef(`SID$1',,`define(SID$1,1)'ifelse(BASE_LANG,c,
`static char x$1[] = "``$2''";',`$1 format(SQUOTEIT(``$2''))'))')

# m4 macro SCCS_ID causes an SCCS version string for a .m, .r, .C, or .i
# file to be part of the end product object file. The string identifies the
# filename, its SCCS version number, and (for .m's) which file included it.
# The macro sets a flag so that the version string is produced exactly once
# per .m file, no matter how many times that file is INCLUDE'd during an m4
# input stream. The macro works for both C and ratfor as base language.  If
# C, the string is the initialized value of a char array.  If ratfor, it's
# part of a dummy format statement.
# 
# 
# See .[mrCi] files for example usage; note that an extra set of m4 quotes
# around the @ (#) is needed for .i's, and that the extra identificaton
# "From BASEFILE" appears in .m's. (BASEFILE is defined on the m4 command
# line in $C/makehead.) 
# 
# In addition, the global m4 header files mach.m, ratfor.m, cdefs.m, and
# intf.m handle the identification strings a little differently.  m4 macro
# SCCS_M4_ID holds the results of various SCCS_ID instances among these
# files; SCCS_M4_ID should appear in ratfor and .C files in addition to
# SCCS_ID.
# 
# The first argument to SCCS_ID should be a five-digit number starting with
# 9, and be unique among all files used in producing a given .o module.  It
# is used to generate both a C identifier or Fortran format tag, and an m4
# macro (flag).

divert(xSTREAMx)
